home *** CD-ROM | disk | FTP | other *** search
/ MacFormat 1995 January / macformat-020.iso / Shareware City / Applications / Alpha.5.96 folder / Tcl / UserCode / MacPerl.tcl.old < prev    next >
Encoding:
Text File  |  1994-08-07  |  20.9 KB  |  662 lines  |  [TEXT/ALFA]
  1. #############################################################################
  2. # MacPerl.tcl
  3. #
  4. # This is a set of routines that allow Alpha to act as a front end for the
  5. # standalone MacPerl application and that allow Perl scripts to be used as 
  6. # text filters in Alpha.
  7. #
  8. #############################################################################
  9. # Features:
  10. #
  11. # A Perl menu is created that allows the following actions:
  12. #
  13. # 1.  Selected text (or the entire buffer) may be interpreted as a Perl 
  14. #     script by MacPerl.
  15. #    
  16. # 2.  A selected Perl script file may be executed by MacPerl.
  17. #
  18. # 3.  Perl scripts that read from standard input and write to standard
  19. #     output may be used as text filters within Alpha.  
  20. #
  21. #     A submenu of "preattached" Perl scripts is constructed from the 
  22. #     contents of a "Text Filters" folder within the main MacPerl folder.
  23. #     This folder will be created if it doesn't already exist.
  24. #
  25. #     Besides the "preattached" filters, a disk file or an Alpha buffer
  26. #     which contains a Perl script may be chosen as the text filter.
  27. #     (The latter option allows simple one-time scripts to be created and 
  28. #     applied on the fly.  This can be very useful because, even
  29. #     with the overhead to start up MacPerl, large-scale global search-
  30. #     and-replace operations (hundreds of replaces) are substantially faster
  31. #     in MacPerl than in Alpha.)
  32. #
  33. #     The output of Perl text filters may be chosen to overwrite the 
  34. #     selected Alpha text or else written into a new window.  (Everything 
  35. #     is undoable, in any case).
  36. #
  37. #     The filter may be applied either to the currently selected text
  38. #     or to the entire buffer.
  39. #
  40. # 4.  The temporary i/o files used by the text filter mechanism may be 
  41. #     examined.
  42. #
  43. # 5.  The Perl menu may be rebuilt, in case files are added or removed 
  44. #     from the "Text Filters" folder.
  45. # 
  46. # A sampling of useful :-) Perl scripts are included in the folder "Text 
  47. # Filters", in the :Tcl:UserCode folder.
  48. # 
  49. # You should drag this folder into your MacPerl folder, where MacPerl.tcl 
  50. # will look for it.  The "Text Munging" scripts are largely from the 
  51. # Nutshell book ("Programming Perl") and the s2p script is my adaptation 
  52. # of the standard script that converts Unix "sed" scripts to Perl (adapted 
  53. # to work without using the C preprocessor).  The others may be useful 
  54. # examples as well.
  55. # 
  56. #############################################################################
  57. #
  58. # If you don't already have MacPerl, it's available by anonymous ftp from
  59. # the umich site
  60. #
  61. #   mac.archive.umich.edu    [141.211.165.34]    mac/development/languages                            (4)
  62. #
  63. # and its mirrors.  Also, MacPerl's home site is 
  64. #
  65. #   ftp.switch.ch            [130.59.1.40]        software/mac/src/mpw_c
  66. #
  67. # MacPerl was written (ported to the Mac) by 
  68. #        Matthias Neeracher <neeri@iis.ee.ethz.ch> , and
  69. #        Tim Endres <time@ice.com>.
  70. #
  71. #############################################################################
  72. # Authors: W. Thomas Pollard (pollard@chem.columbia.edu)
  73. #          Martijn Koster (m.koster@nexor.co.uk)
  74. #
  75. # Version History:
  76. #
  77. # 1.1  8/94  -  'quitMacperl' added.
  78. #               perl-mode file-marking updated for Alpha 5.90
  79. #               Simplified installation via 'loadMacperl'(Pete Keleher). 
  80. # 1.0  7/94  -  perl-mode setup updated for Alpha 5.85:
  81. #                    keyword colorization supported
  82. #                    custom file-marking added
  83. #               #! lines in filter scripts now handled correctly 
  84. #               Workarounds installed for AppleEvent bug in MacPerl 4.1.3
  85. # 0.9  3/94  -  perl-mode stuff added, and
  86. #               highlighted 'Perl commands' file (man page) prepared
  87. #               minor bug fixes, too
  88. # 0.8  3/94  -  flags are now check-marked
  89. # 0.7  3/94  -  nested Text Filters folder now supported
  90. #               menu format modified somewhat
  91. # 0.6  3/94  -  'applyToBuffer' flag added
  92. #               scripts in Alpha buffers can now be used as filters 
  93. # 0.5  2/94  -  'filters', 'open special' submenu added
  94. #               'overwrite' flag added
  95. # 0.2  1/94  -  menu support added (MK)
  96. #               'execute selection', 'execute buffer' commands added
  97. # 0.1  9/93  -  text filter functionality created (WTP)
  98. #                  
  99. #   Comments, suggestions, bug reports, etc., should be directed to 
  100. #   Tom Pollard (pollard@chem.columbia.edu).
  101. #
  102. #############################################################################
  103. #  Default settings for the Perl mode flags  
  104. #
  105. set perlOverwrite 1
  106. set perlUsebuffer 1
  107.  
  108. #############################################################################
  109. #  To install the MacPerl package, the user is prompted to locate his
  110. #  MacPerl application.  This information (necessary for building the MacPerl
  111. #  menu) recorded in UserStartup.tcl, along with commands that will load
  112. #  MacPerl mode automatically in the future.
  113. #
  114. proc loadMacPerl {} {
  115.     global macperlPath mode
  116.     if {[askyesno "Install MacPerl mode?"] == "yes"} {
  117.         set f [getfile {Where is your MacPerl application?"}]
  118.         
  119.         # modify UserStartup.tcl so that Perl mode loads automatically
  120.         addUserLine "\r\# The next several lines enable MacPerl mode."
  121.         addUserLine "set macperlPath \"$f\""
  122.         addUserLine "enableMenuItem install macPerl 0"
  123.         addUserLine "lappend modes Perl"
  124.         addUserLine "set dummyProc(Perl) dummyPerl"
  125.         addUserLine "set modeMenus(Perl) { perlMenu }"
  126.         addUserLine "lappend modeSuffixes {*.pl} { set winMode Perl }"
  127.         addUserLine "newModeVar Perl elecRBrace {0} 1"
  128.         addUserLine "newModeVar Perl electricSemi {0} 1"
  129.         addUserLine "newModeVar Perl wordBreak {(\$)?[a-zA-Z0-9_]+} 0"
  130.         addUserLine "newModeVar Perl prefixString {# } 0"
  131.         addUserLine "newModeVar Perl elecLBrace {0} 1"
  132.         addUserLine "newModeVar Perl wordWrap {0} 1"
  133.         addUserLine "newModeVar Perl funcExpr {^sub *([+-a-zA-Z0-9]+)} 0"
  134.         addUserLine "newModeVar Perl wordBreakPreface {[^a-zA-Z0-9_\$]} 0"
  135.         addUserLine "newModeVar Perl optionIsMeta {1} 1\r\r"
  136.         
  137.         # enable Perl mode for this session
  138.         set macperlPath $f
  139.         rebuildPerlMenu
  140.         buildModeFlagMenu
  141.         enableMenuItem install macPerl 0
  142.  
  143.         # reset the mode, so that Perl menu is inserted if required
  144.         set currentMode $mode
  145.         changeMode none
  146.         changeMode $currentMode
  147.     }
  148. }
  149.  
  150. #############################################################################
  151. #  Return paths to standard files, based on the path to MacPerl:
  152. #
  153. proc macperlFolder {} {
  154.    global macperlPath
  155.    regexp {(.*):([^:]*)} $macperlPath pathname dirname filename
  156.    return ${dirname}:
  157. }
  158.  
  159. proc stdinPath {} {
  160.    return [macperlFolder]STDIN
  161. }
  162.  
  163. proc stdoutPath {} {
  164.    return [macperlFolder]STDOUT
  165. }
  166.  
  167. proc scriptPath {} {
  168.    return [macperlFolder]SCRIPT
  169. }
  170.  
  171. proc scriptFolder {} {
  172.    return "[macperlFolder]Text Filters:"
  173. }
  174.  
  175. #############################################################################
  176. #  Toggle the "overwrite" flag.  If true, then the output of a Perl filter
  177. #  is inserted in place of the originally selected text.  Otherwise, it is
  178. #  placed in a new window.  The names of the routines reflect the condition
  179. #  of the flag _before_ the routine is called, so that the menu makes more
  180. #  sense.
  181. # 
  182. proc overwriteSelection {} {
  183.     global perlMenu perlOverwrite
  184.     if {$perlOverwrite} then {
  185.         set perlOverwrite 0
  186.     } else {
  187.         set perlOverwrite 1
  188.     }
  189.     markMenuItem $perlMenu overwriteSelection $perlOverwrite
  190. }
  191.  
  192. #############################################################################
  193. #  Toggle the "usebuffer" flag.  If true, then the Perl filter is applied to 
  194. #  the entire buffer.  Otherwise, only the selected text is filtered.
  195. # 
  196. proc applyToBuffer {} {
  197.     global perlMenu perlUsebuffer
  198.     if {$perlUsebuffer} then {
  199.            set perlUsebuffer 0
  200.     } else {
  201.            set perlUsebuffer 1
  202.     }
  203.     markMenuItem $perlMenu applyToBuffer $perlUsebuffer
  204. }
  205.  
  206. #############################################################################
  207. #  This is a generally useful proc that builds a hierarchical menu 
  208. #  from the files in a given folder and all subfolders.  As the menu is
  209. #  built, the pathnames of the various files are saved in the array
  210. #  indicated  by $filePaths.  The index of the file's path in this array
  211. #  is formed by concatenating the submenu name and filename, allowing the
  212. #  pathname to be retrieved by the procedure $proc when the menu item is
  213. #  selected.
  214. #
  215. proc buildSubMenu {folder name proc filePaths} {
  216.     global $filePaths
  217.     if {$name == 0} {
  218.         set name [file tail [file dirname $folder]]
  219.     }
  220.     if {$proc == 0} {
  221.         set pproc ""
  222.     } else {
  223.         set pproc "-p $proc"
  224.     }
  225.     set menu {}
  226.     set filenames [glob -nocomplain  $folder\*]
  227.     if {[llength $filenames] > 0} {
  228.        foreach m $filenames {
  229.           if {[file isdirectory $m]} {
  230.               lappend menu [buildSubMenu ${m}: 0 $proc $filePaths] 
  231.           } elseif {[file isfile $m]} {
  232.               set fname [file tail $m]
  233.               lappend menu $fname
  234.               set ${filePaths}($name:$fname) $m
  235.           }
  236.          }
  237.     }
  238.     return [concat {menu -m -n} [list $name] $pproc [list $menu]]
  239. }
  240.  
  241. #############################################################################
  242. #  Build a submenu of "preattached" Perl filters using the names of the 
  243. #  scripts in the Text Filters directory
  244. #
  245. proc perlFilterMenu {} {
  246.     global perlFilterPath HOME
  247.     set scriptDir [scriptFolder]
  248.     if {![file exists $scriptDir]} {
  249.        message "Copying \":Tcl:UserCode:Text Filters\" to MacPerl folder." 
  250.        cphier "$HOME:Tcl:UserCode:Text Filters" [macperlFolder]
  251.        message ""
  252.     }
  253.     return [buildSubMenu $scriptDir TextFilters perlExecuteFilter perlFilterPath]
  254. }
  255.  
  256. proc rebuildPerlMenu {} {
  257.     global perlMenu perlOverwrite perlUsebuffer
  258.             
  259.     set perlMenu "•132"
  260.     menu -n $perlMenu [ concat {
  261.         "macperl/-"
  262.         "(-"
  263.         "runTheSelection"
  264.         "runTheBuffer"
  265.         "runAFile"
  266.         "(-"
  267.         } [list [perlFilterMenu]] {
  268.         {menu -n OtherTextFilters {
  269.            "selectABuffer"
  270.            "selectAFile"
  271.            }
  272.         } 
  273.         "applyToBuffer"
  274.         "overwriteSelection"
  275.         "(-"
  276.         {menu -m -n openSpecial -p perlOpenFile {
  277.            "STDIN"
  278.            "STDOUT"
  279.            "SCRIPT"
  280.            }
  281.         } 
  282.         "(-"
  283.         "rebuildPerlMenu"
  284.         "quitMacperl"
  285.         } ]
  286.     perlMenuSetFlags
  287. }
  288.  
  289. proc perlMenuSetFlags {} {
  290.     global perlMenu perlOverwrite perlUsebuffer
  291.     markMenuItem $perlMenu overwriteSelection $perlOverwrite
  292.     markMenuItem $perlMenu applyToBuffer $perlUsebuffer
  293. }
  294.  
  295. if ([info exists macperlPath]) {
  296.     rebuildPerlMenu
  297. }
  298.  
  299. #############################################################################
  300. # Switch to MacPerl:
  301. # 
  302. proc macperl {} {
  303.     global macperlPath
  304.     set name [checkRunning MacPerl McPL macperlPath]
  305.     if {[string length $name]} {
  306.         switchTo "MacPerl"
  307.     } else {
  308.         alertnote "Couldn't run MacPerl"
  309.     }
  310. }
  311.  
  312. #############################################################################
  313. # Quit a running MacPerl app:
  314. # 
  315. proc quitMacperl {} {
  316.     foreach proc [processes] {
  317.         set sig [lindex $proc 1]
  318.         if {$sig == "McPL"} {
  319.             sendQuitEvent [lindex $proc 0]
  320.             # switchTo is necessary to keep MacPerl from blinking
  321.             switchTo [lindex $proc 0]    
  322.         }
  323.     }
  324. }
  325.  
  326. proc sendQuitEvent {appname} {
  327.     AEBuild $appname aevt quit 
  328. }
  329.  
  330. #############################################################################
  331. #
  332. proc perlOpenFile {menu name} {
  333.     set filename [macperlFolder]$name
  334.     if {[file exists $filename]} {
  335.         edit $filename
  336.     } else {
  337.         alertnote "That file doesn't exist yet"
  338.     }
  339. }
  340.  
  341. #############################################################################
  342. # Get a script file to run under MacPerl:
  343. #
  344. proc runAFile {} {
  345.     if {! [catch {getfile "Select a Perl script"} path]} {
  346.             perlExecuteFile $path
  347.     }
  348. }
  349.  
  350. #############################################################################
  351. # Tell MacPerl to run a script file:
  352. #
  353. proc perlExecuteFile {path} {
  354.     global macperlPath
  355.     if {[string length $path]} {
  356.         set name [checkRunning MacPerl McPL macperlPath]
  357.         if {[string length $name]} {
  358.             dosc -c 'McPL' -r -f $path
  359.             switchTo "MacPerl"
  360.         } else {
  361.             alertnote "Couldn't run MacPerl"
  362.         }
  363.     } else {
  364.             alertnote "No file specified to execute"
  365.     }
  366. }
  367.  
  368. #############################################################################
  369. # Run the buffer as a MacPerl script:
  370. #
  371. proc runTheBuffer {} {
  372.     perlExecuteScript [getText 0 [maxPos]]
  373. }
  374.  
  375. #############################################################################
  376. # Run the selection as a MacPerl script:
  377. # (No special arrangements are made to provide input or capture the output)
  378. # 
  379. proc runTheSelection {} {
  380.     perlExecuteScript [getSelect]
  381. }
  382.  
  383. #############################################################################
  384. # Run a MacPerl script, passed explicitly as a string:
  385. # (No special arrangements are made to provide input or capture the output)
  386. # 
  387. proc perlExecuteScript {script} {
  388.     global macperlPath
  389.     if {$script != ""} {
  390. # MacPerl 4.1.3 bug 
  391.         writeScript $script
  392.         set name [checkRunning MacPerl McPL macperlPath]
  393.         if {[string length $name]} {
  394. # MacPerl 4.1.3 bug
  395. #             dosc -c 'McPL' -r -s $script         
  396. # MacPerl 4.1.3 bug 
  397.             dosc -c 'McPL' -r -f [scriptPath]    
  398.             switchTo "MacPerl"
  399.        } else {
  400.             alertnote "Couldn't run MacPerl"
  401.        }
  402.     } else {
  403.         alertnote "Empty script"
  404.     }
  405. }
  406.  
  407. #############################################################################
  408. # Run a Perl script filter selected from the menu:
  409. #
  410. proc perlExecuteFilter {menu name} {
  411.     global perlFilterPath
  412.     set path $perlFilterPath($menu:$name)
  413.     set coreScript [readFile $path]
  414.     if {$coreScript != -1} {
  415.         set script [wrapFilterScript $coreScript]
  416.         filterThruMacperl $script
  417.     } else {
  418.         alertnote "Couldn't read the script file : $path"
  419.         return
  420.     }
  421. }
  422.  
  423. #############################################################################
  424. # Ask for a file containing a Perl script to use as a filter:
  425. #
  426. proc selectAFile {} {
  427.     if {! [catch {getfile "Select a MacPerl script"} path]} {
  428.         set coreScript [readFile $path]
  429.         if {$coreScript != -1} {
  430.             set script [wrapFilterScript $coreScript]
  431.             filterThruMacperl $script
  432.         } else {
  433.             alertnote "Couldn't read the script file : $path"
  434.             return
  435.         }
  436.     }
  437. }
  438.  
  439. #############################################################################
  440. # Ask for an Alpha buffer containing a Perl script to use as a filter:
  441. #
  442. proc selectABuffer {} {
  443.     set windows [winNames]
  444.     if {[llength $windows] > 1} {
  445.         set current [lindex $windows 0]
  446.         set name [listpick [lsort $windows]]
  447.         if {[string length $name]} {
  448.             bringToFront $name
  449.             set coreScript [getText 0 [maxPos]]
  450.             if {[string length $coreScript]} {
  451.                 set script [wrapFilterScript $coreScript]
  452.                 bringToFront $current
  453.                 filterThruMacperl $script
  454.             } else {
  455.                 bringToFront $current
  456.             }
  457.            }
  458.     }
  459. }
  460.  
  461. #############################################################################
  462. # Filter selection through a Perl script:
  463. # 
  464. proc filterThruMacperl {script} {
  465.     global macperlPath perlOverwrite perlUsebuffer
  466.  
  467.     set name [checkRunning MacPerl McPL macperlPath]
  468.     if {[string length $name]} {
  469.         writeStdin
  470.         writeStdout
  471. # MacPerl 4.1.3 bug
  472. #        dosc -c 'McPL' -t 0 -s $script             
  473. # MacPerl 4.1.3 bug 
  474.         dosc -c 'McPL' -t 0 -f [scriptPath]        
  475.     } else {
  476.         alertnote "Couldn't run MacPerl"
  477.     }
  478.     
  479.     if {!$perlOverwrite} new
  480.     if {$perlUsebuffer} {
  481.         pasteStdout 0 [maxPos]
  482.     } else {
  483.         pasteStdout [getPos] [selEnd]
  484.     }
  485. }
  486.  
  487. #############################################################################
  488. #  Take a Perl script and add commands to take the file STDIN as standard
  489. #  input and STDOUT as standard output.  This allows scripts written as
  490. #  Unix command-line filters to be used in the (non-MPW) Mac environment as
  491. #  text filters.
  492. #
  493. #  If there's already a #! line in the script, then the new commands
  494. #  are added after that line.  If there was no #! line in the first place,
  495. #  one is added, in case MacPerl is set up to require it (can't hurt...) 
  496. #
  497. proc wrapFilterScript {coreScript} {
  498.  
  499.     if {[regexp -indices {(#![     !-~]*)} $coreScript allofit cmdln]} {
  500.         set endPos [lindex $cmdln 1]
  501.         set filterHead [string range $coreScript 0 [expr $endPos+1]]
  502.         set coreScript [string range $coreScript [expr $endPos+2] end]
  503.     } else {
  504.         set filterHead "#!/bin/perl\n"
  505.     }
  506.     append filterHead "\$macperlDir = \"[macperlFolder]\" ;\n"
  507.     append filterHead "open(STDIN, \"<[stdinPath]\" ) ;\n"
  508.     append filterHead "open(STDOUT, \">[stdoutPath]\" ) ;\n"
  509.     append filterHead "@ARGV = (\"[stdinPath]\") ;\n"
  510.     append filterHead "select(STDOUT) ;\n\n"
  511.     
  512.     set filterTail "close STDIN ;\nclose STDOUT ;\n"
  513.         
  514.     set script $filterHead
  515.     append script $coreScript
  516.     append script $filterTail
  517.     
  518.     writeScript $script
  519.     return $script
  520. }        
  521.  
  522. #############################################################################
  523. #  Paste the text of the file STDOUT in place of the current selection.
  524. #
  525. proc pasteStdout {from to} {
  526.     set result [readFile [stdoutPath]]
  527.     if {$result != -1} {
  528.         deleteText $from $to
  529.         insertText $result
  530.         catch shrinkWindow
  531.         goto 0
  532.     } else {
  533.         alertnote "Couldn't find the output file : STDOUT"
  534.     }
  535. }    
  536. #        replaceText [getPos] [selEnd] $result
  537.  
  538. #############################################################################
  539. #  Extend the current selection to encompass complete lines.  If the 
  540. #  'applyToBuffer' flag is checked, then the entire buffer is selected.
  541. #
  542. proc completeSelection {} {
  543.     global perlUsebuffer
  544.     if {$perlUsebuffer} {
  545.         set start 0
  546.         set end [maxPos]
  547.     } else {
  548.         set start [lineStart [getPos]]
  549.         set end [nextLineStart [expr [selEnd]-1]]
  550.     }
  551.     if {$end == $start} {set end [nextLineStart [selEnd]]}
  552.     select $start $end
  553. }
  554.  
  555. #############################################################################
  556. #  writeStdin: Extend the selection, as appropriate, and write it to the 
  557. #     STDIN file in the MacPerl directory.
  558. #  writeStdout: Write the extended selection to the STDOUT file.  This will
  559. #      then be the default output in case MacPerl hangs. 
  560. #  writeScript: Write the SCRIPT file in the MacPerl directory.  This is
  561. #     only useful for debugging - it's not used by the rest of the code. 
  562. #
  563. proc writeStdin {} {
  564.     completeSelection
  565.     set tmpfid [open [stdinPath] "w+"]
  566.     puts $tmpfid [getSelect] 
  567.     close $tmpfid
  568. }
  569.  
  570. proc writeStdout {} {
  571.     completeSelection
  572.     set tmpfid [open [stdoutPath] "w+"]
  573.     puts $tmpfid [getSelect] 
  574.     close $tmpfid
  575. }
  576.  
  577. proc writeScript {script} {
  578.     set tmpfid [open [scriptPath] "w+"]
  579.     puts $tmpfid $script 
  580.     close $tmpfid
  581. }
  582.  
  583. #############################################################################
  584. #  Read and return the complete contents of the specified file.
  585. #
  586. proc readFile {fileName} {
  587.     if {[file exists $fileName] && [file readable $fileName]} {
  588.        set fileid [open $fileName "r"]
  589.        set contents ""
  590.        while {[gets $fileid nextLine] != -1} {
  591.           append contents $nextLine "\n"
  592.        }
  593.        close $fileid
  594.        return $contents
  595.     } else {
  596.        return -1
  597.     }
  598. }
  599.  
  600. ##############################################################################
  601. # Automatic subroutine marking for Perl mode in Alpha 5.85
  602. #
  603. # (code stolen shamelessly from 'tclMarkFile' in 'tcl.tcl')
  604. #
  605.  
  606. proc PerlMarkFile {} {
  607.     set end [maxPos]
  608.     set pos 0
  609.     set l {}
  610.     while {![catch {search -f 1 -r 1 -m 0 -i 0 {^sub} $pos} res]} {
  611.         set start [lindex $res 0]
  612.         set end [nextLineStart $start]
  613.         set text [lindex [getText $start $end] 1]
  614.         set pos $end
  615.         set inds($text) [lineStart [expr $start - 1]]
  616.     }
  617.  
  618.     if {[info exists inds]} {
  619.         foreach f [lsort [array names inds]] {
  620.             set next [nextLineStart $inds($f)]
  621.             setNamedMark $f $inds($f) $next $next
  622.         }
  623.     }
  624. }
  625.  
  626. proc dummyPerl {} {
  627. }
  628.  
  629. ##############################################################################
  630. # Perl mode definitions  (for Alpha 5.85+)
  631. #
  632.  
  633. set perlKeywords {
  634. accept alarm atan2 bind binmode caller chdir chmod chop chown chroot 
  635. close closedir connect continue cos crypt dbmclose dbmopen defined 
  636. delete die do dump each else elsif eof eval exec exit exp fcntl fileno 
  637. flock for foreach fork getc getlogin getpeername getpgrp getppid 
  638. getpriority getgrnam gethostbyname getnetbyname getprotobyname getpwuid 
  639. getgrgid getservbyname gethostbyaddr getnetbyaddr getprotobynumber 
  640. getservbyport getpwent getgrent gethostent getnetent getprotoent 
  641. getservent setpwent setgrent sethostent setnetent setprotoent setservent 
  642. endpwent endgrent endhostent endnetent endprotoent endservent 
  643. getsockname getsockopt gmtime goto grep hex if index int ioctl join keys 
  644. kill last length link listen local localtime log lstat lstat mkdir 
  645. msgctl msgget msgsnd msgrcv next oct open opendir ord pack pipe pop 
  646. print print printf printf push q qq qx rand read readdir readlink recv 
  647. redo rename require reset return reverse rewinddir rindex rindex rmdir 
  648. scalar seek seekdir select semctl semget semop send setpgrp setpriority 
  649. setsockopt shift shmctl shmget shmread shmwrite shutdown sin sleep 
  650. socket socketpair sort splice split sprintf sqrt srand stat study sub 
  651. substr symlink syscall sysread system syswrite tell telldir time times 
  652. tr truncate umask undef unless unlink unpack unshift until utime values 
  653. vec wait waitpid wantarray warn while write eq ne cmp lt gt le ge @_ $_ $.  
  654. $/ $, $" $\\ $\# $% $= $- $~ $^ $| $$ $? $& $` $' $+ $* $0 $1 $2 $3 $4 $5 
  655. $6 $7 $8 $9 $[ $] $; $! $@ $< $> $( $) $: $^D $^F $^I $^P $^T $^W $^X 
  656. $ARGV @ARGV @INC %INC $ENV $SIG
  657. }
  658. regModeKeywords -e {#} -c red -k blue Perl $perlKeywords
  659. unset perlKeywords
  660.  
  661. ##############################################################################
  662.